# Создание web-страниц с доступом к MATLAB

## 4. Загрузка web-страницы

    Dim MatLab, ver, fso, cpath
    Set MatLab = Nothing
    Set fso = Nothing
    Set fso = CreateObject("Scripting.FileSystemObject")
    cpath = GetCurrPath()
    call LoadAllArea()

    function GetCurrPath() ' создаёт при необходимости и возвращает имя временного каталога
      Dim tf, slp, ma, ub, newf
      tf = fso.GetSpecialFolder(2)
      slp = self.location.pathname
      slp = replace(slp,"/","\") ' убрали символ /
      slp = replace(slp,".","\") ' убрали символ .
      ma = split(slp,"\",-1,1) ' уазделяем строку по знаку \
      ub = Ubound(ma) ' количество записей
      tf = tf & "\" & ma(ub-1)
      if not (fso.FolderExists(tf)) then
        Set newf = fso.CreateFolder(tf)
        tf = newf.Path
      end if
      GetCurrPath = tf
    end function

    sub LoadAllArea() ' загружает все области ввода и вывода
      Dim lentag, k, cn, idn, fn
      lentag = document.all.length ' количество тэгов
      for k=0 to lentag-1
        cn = lcase(document.all(k).className)
        idh = document.all(k).id
        if cn="inparea" then
          fn = cpath & "\" & idh & ".txt"
          if (fso.FileExists(fn)) then
            execute("call LoadInp(document.all." & idh & ",""" & fn & """)" )
          end if
        elseif cn="outarea" then
          fn = cpath & "\" & idh & ".txt"
          if (fso.FileExists(fn)) then
            execute("call LoadOut(document.all." & idh & ",""" & fn & """)" )
          end if
        end if
      next
    end sub

    sub LoadInp(MyInp,FileName) ' загружает область ввода из файла
      Dim mf
      Set mf = fso.OpenTextFile(FileName,1)
      MyInp.Value = mf.ReadAll
      mf.close
    end sub

    sub LoadOut(MyOut,FileName) ' загружает область вывода из файла
      Dim mf
      Set mf = fso.OpenTextFile(FileName,1)
      MyOut.innerHTML = mf.ReadAll
      mf.close
    end sub